10 REM ******************************
20 REM *       COPY 1202/600        *
30 REM *   (c) 1986 by Arndt Baer   *
40 REM ******************************
50 REM * ZUERST CBAUD 1200/1 LAUFEN *
60 REM *        LASSEN !!!!!!!      *
70 REM ******************************
80 POKE 65,1:RAM=INT(PEEK(54017)/2)*2:POKE 54017,RAM+1
90 DIM ML$(51):BASTOP=INT((PEEK(144)+256*PEEK(145)+100)/256):MEMLO=INT((BASTOP+2)/2)*2+4:HILEN=(192-MEMLO)*256
100 POKE 106,MEMLO:GRAPHICS 0:POKE 756,204
110 ? :? :? "Wichtig:Um mit 1200 Baud zu kopieren,":? "        muss zuerst CBAUD 1200/1"
120 ? "        eingeladen werden!"
130 FOR I=1 TO 51:READ A:ML$(I,I)=CHR$(A):NEXT I
140 DATA 104,173,1,211,9,2,141,1,211,104,104,170,104,104
150 DATA 157,66,3,104,157,69,3
160 DATA 104,157,68,3,104,157,73
170 DATA 3,104,157,72,3,32,86,228
180 DATA 132,212,169,0,133,213,173,1,211,41,253,141,1,211,96
190 ? :? :? :GOSUB 540
200 GRAPHICS 0:POKE 756,204
210 ? CHR$(125):? " Baercopy 1200/1 ":? "   (c) 1985 by":? "   Arndt  Baer ":POKE 752,1:? HILEN;" Bytes free."
220 BLOCK=0
230 SETCOLOR 2,0,2:SETCOLOR 1,0,12
240 ? :? "EINLADEN mit ":GOSUB 470
250 POSITION 2,ZE1:? :? "< PLAY und RETURN. >"
260 CLOSE #1:OPEN #1,4,128,"C:"
270 ? :? "Programm laedt ":ZEI=PEEK(84)
280 A=USR(ADR(ML$),16,7,MEMLO*256,HILEN)
290 BLOCK=PEEK(856)+256*PEEK(857)
300 POSITION 20,2:? "Laenge: ";BLOCK;" Bytes"
310 IF A<128 THEN LET A=2
320 CLOSE #1:POSITION 2,ZEI:?
330 IF A<>136 THEN GOSUB 530: IF KEY<>27 THEN GOTO 200
340 SETCOLOR 2,13,4:SETCOLOR 1,0,14
350 ? :? "SPEICHERN mit ":GOSUB 470
360 POSITION 2,ZE1:? :? "< PLAY,RECORD und RETURN. >"
370 CLOSE #1:OPEN #1,8,128,"C:"
380 A=USR(ADR(ML$),16,11,MEMLO*256,BLOCK)
390 CLOSE #1:SOUND 0,0,0,0
400 IF A>127 THEN GOSUB 530:GOTO 420
410 ? :? "O.K.":?
420 SETCOLOR 2,12,2:SETCOLOR 1,0,12
430 ? "1...Noch eine Kopie ":? "2...Neues Original":? "3...Ende"
440 CLOSE #2:OPEN #2,4,0,"K:":GET #2,KEY:WAHL=KEY-48
450 ON WAHL GOTO 340,210,460
460 END
470 ? :? "   1..1200 Baud oder":? "   2...600 Baud ? ":ZE1=PEEK(84)
480 CLOSE #2:OPEN #2,4,0,"K:"
490 GET #2,KEY:IF KEY=49 THEN POKE 54017,RAM:GOTO 520
500 IF KEY=50 THEN POKE 54017,RAM+1:GOTO 520
510 GOTO 490
520 POSITION 5,ZE1+KEY-51:? CHR$(27);CHR$(31)
525 RETURN
530 POKE 752,1:? CHR$(125);"I/O - Fehler Nr.";A:? :POKE 54017,RAM+1
540 ? " < beliebige Taste >"
550 CLOSE #2:OPEN # 2,4,0,"K:"
560 GET #2,KEY:RETURN